Como pongo el sistema de niveles?

Nose si sabran que es pero son niveles que se les dan a los monsustros del uno al 10
por ejemplo un eskeleto el nivel 1 encambio un blue dragon nivel 9. Enteienden?

eso , se activa desde el sphere.ini

Código:


///////////////////////////////////////////////////////////////
//////// Experience and Level system
///////////////////////////////////////////////////////////////

//   Enable experience system
//ExperienceSystem=0

//   Experience system settings:
//   0001 gain experience in combat
//   0002 gain experience in crafts
//   0004 allow experience to go down
//   0008 limit experience decrease by a range witheen a current level
//   0010 auto-init EXP/LEVEL for NPCs if not set in @Create
//   0020 allow trigger @ExpChange
//   0040 allow trigger @ExpLevelChange
//ExperienceMode=0

//   If combat experience gain is allowed, use these percents for gaining exp in
//   Player versus Monster and Player versus Player combats. Value 0 disables gain.
//ExperienceKoefPVM=100
//ExperienceKoefPVP=100

//   Enable levels system (as a part of experience system)
//LevelSystem=0

//   Level system settings:
//   linear = 0 (each NextLevelAt exp will give a level up)
//   double = 1 (you need (NextLevelAt * (level+1)) to get a level up)
//LevelMode=1

//   Amount of experience to raise to the next level
//LevelNextAt=0

Cleor q es ahy .
cualquier cosa postea . me fijo bien ;D

// Enable experience system
ExperienceSystem=1
// Experience system settings:
// 0001 gain experience in combat
// 0002 gain experience in crafts
// 0004 allow experience to go down
// 0008 limit experience decrease by a range witheen a current level
// 0010 auto-init EXP/LEVEL for NPCs if not set in @Create
// 0020 allow trigger @ExpChange
// 0040 allow trigger @ExpLevelChange
ExperienceMode=0010
// If combat experience gain is allowed, use these percents for gaining exp in
// Player versus Monster and Player versus Player combats. Value 0 disables gain.
ExperienceKoefPVM=100
ExperienceKoefPVP=275
// Enable levels system (as a part of experience system)
LevelSystem=1
// Level system settings:
// linear = 0 (each NextLevelAt exp will give a level up)
// double = 1 (you need (NextLevelAt * (level+1)) to get a level up)
LevelMode=1
// Amount of experience to raise to the next level
LevelNextAt=500





Yo lo tengo asi pero no funciona.

Te fijaste en "Sphere.ini - Tutoriales" , para ver si encontras algo de ayuda???

nada pss

Código:

[CHARDEF C_DRAGON_QUEEN]
ID=C_ANCIENT_WYRM
NAME=Dragon Queen
DAM=65,81
ARMOR=58
CAN=MT_WALK|MT_FLY|MT_USEHANDS
MOVERATE=35
CATEGORY=Addon
SUBSECTION=Evo Dragons
DESCRIPTION=Dragon Queen

ON=@Create
NPC=BRAIN_DRAGON
KARMA=-6000
FAME=6000
STR={400 500}
MAXHITS={2000 3000}
DEX={200 300}
INT={400 500}
MAGERY={100.0 120.0}
TACTICS={90.0 110.0}
WRESTLING={80.0 100.0}
ITEMNEWBIE=i_spellbook
ADDCIRCLE 8,1

ON=@Death
FINDID.i_evo_egg.MORE1=<RTIME.DAY>

ON=@NPCRestock
ITEM=i_evo_egg
ITEM=i_gold{2200 3000}
ITEM=i_mapa_tesouro

[ITEMDEF i_evo_egg]
ID=i_white_pearl
NAME=Evo Egg
TYPE=T_NORMAL
VALUE=100000

ON=@Create
COLOR=0485

ON=@Dclick
IF (<CONT>)
IF (<TOPOBJ.UID>==<SRC>)
IF (<MORE1>!=<RTIME.DAY>)
SERV.NEWNPC=C_SNAKE
NEW.KARMA=0
NEW.FAME=0
NEW.NAME=dragon hatchling
NEW.EVENTS +e_evo_dragon
NEW.TAG.BONDEDP=<SRC.P>
NEW.STR=200
NEW.DEX=200
NEW.INT=200
NEW.HITS=<NEW.MAXHITS>
NEW.STAM=<NEW.MAXSTAM>
NEW.MANA=<NEW.MAXMANA>
NEW.P=<SRC.P>
NEW.UPDATE
LOCAL.NEW=<NEW>
SRC.TAME=<NEW>
SERV.NEWITEM i_evo_dragon_remover
NEW.CONT=<LOCAL.NEW>
NEW.TIMER=<EVAL 60*60*24*3>
CONSUME 1
ENDIF
ENDIF
ENDIF

[ITEMDEF i_evo_dragon_remover]
ID=i_memory
TYPE=T_EQ_SCRIPT
NAME=Evo dragon remover

ON=@Timer
CONT.REMOVE

[EVENTS e_evo_dragon]
ON=@Kill
FINDID.i_evo_dragon_remover.TIMER=<EVAL 60*60*24*3>
IF !(<TAG0.KP> > 17500000)
TAG0.KP += <eval (((<argo.maxhits>)+(<argo.dex>)+(<argo.int>))*3)+100>
IF (<TAG0.KP> >= 25000) && (<OBODY>==C_SNAKE)
BODY=C_MONGBAT
OBODY=C_MONGBAT
NAME=giange hatchling
STR += 200
DEX += 50
INT += 150
ELIF (<TAG0.KP> >= 75000) && (<OBODY>==C_MONGBAT)
BODY=C_M_IMP
OBODY=C_M_IMP
MAGERY=60.0
NAME=dragon imp
STR += 200
DEX += 50
INT += 150
ELIF (<TAG0.KP> >= 275000) && (<OBODY>==C_M_IMP)
BODY=C_DRAGON_SMALL_RED
OBODY=C_DRAGON_SMALL_RED
NPC=BRAIN_DRAGON
MAGERY=70.0
NAME=young dragon
STR += 200
DEX += 50
INT += 150
ELIF (<TAG0.KP> >= 2750000) && (<OBODY>==C_DRAGON_SMALL_RED)
BODY=C_DRAGON_RED
OBODY=C_DRAGON_RED
MAGERY=90.0
NAME=older dragon
STR += 200
DEX += 50
INT += 150
ELIF (<TAG0.KP> >= 4750000) && (<OBODY>==C_DRAGON_RED)
BODY=C_WYVERN_MUTANT
OBODY=C_WYVERN_MUTANT
MAGERY=120.0
NAME=mature dragon
STR += 200
DEX += 50
INT += 150
ELIF (<TAG0.KP> >= 17500000) && (<OBODY>==C_WYVERN_MUTANT)
BODY=C_ANCIENT_WYRM
OBODY=C_ANCIENT_WYRM
TAG.KP=18000000
MAGERY=150.0
NAME=eldar dragon
STR += 200
DEX += 50
INT += 150
ENDIF
UPDATE
ENDIF

ON=@Death
IF !(<ACT.ISPLAYER>)
IF (<OBODY>!=C_WYVERN_MUTANT) && (<OBODY>!=C_ANCIENT_WYRM) && (<OBODY>!=C_DRAGON_RED)
IF !(<ISEMPTY <TAG.BONDEDP>>)
GO <TAG0.BONDEDP>
HITS=<MAXHITS>
MANA=<MAXMANA>
STAM=<MAXSTAM>
ACTION -1
RETURN 1
ENDIF
ENDIF
ENDIF

ON=@EnvironChange
IF !(<FLAGS>&statf_pet)
REMOVE
ENDIF

ON=@ClientToolTip
SRC.ADDCLILOC 1042971,KP : <EVAL <TAG0.KP>>

[EOF]

Código:

[DEFNAME TAMING_SETTINGS]
TAMING_RELEASED_REMOVETIME 60*60*24

[ITEMDEF i_taming_timer]
NAME=Taming Timer
ID=i_memory
TYPE=t_eq_script
LAYER=layer_special

ON=@create
attr=attr_invis|attr_decay

on=@equip
LOCAL.TIME=<EVAL (200-((<SRC.TAMING>/20)+(<SRC.ANIMALLORE>/20)))/15>
IF (<LOCAL.TIME> > 10)
LOCAL.TIME=10
ENDIF
MORE1=<LOCAL.TIME>
TIMER=1

ON=@Timer
IF (<LINK.FLAGS>&statf_pet)
CONT.SYSMESSAGELOC 946,3,502467
CONT.EVENTS -e_taming_pod
REMOVE
RETURN 1
ENDIF
IF !(<CONT.USECHECKS <LINK>>)
CONT.SYSMESSAGELOC 946,3,502800
CONT.EVENTS -e_taming_pod
REMOVE
RETURN 1
ENDIF
IF !(<more1>)
IF (<LINK.ISPK>)
LOCAL.DIFF=140
ELSE
LOCAL.DIFF=90
ENDIF
IF (<R<LOCAL.DIFF>> < <R<EVAL ((<cont.taming>/3)+((<cont.animallore>/3)*2)+(<cont.herding>/4))/10>>) || (<CONT.ISGM>)
TRYSRC <CONT> LINK.MESSAGELOC 946,3,502799
CONT.TAME <LINK>
LINK.UPDATE
CONT.SKILLGAIN Taming 5
CONT.EVENTS -e_taming_pod
REMOVE
RETURN 1
ELSE
CONT.SYSMESSAGELOC 946,3,502798
CONT.SKILLGAIN Taming 20
CONT.EVENTS -e_taming_pod
REMOVE
RETURN 1
ENDIF
ENDIF
MORE1 -= 1
DORAND 4
TRYSRC <CONT> CONT.SAYLOC 946,3,502790
TRYSRC <CONT> CONT.SAYLOC 946,3,502791
TRYSRC <CONT> CONT.SAYLOC 946,3,502792
TRYSRC <CONT> CONT.SAYLOC 946,3,502793
ENDDO
CONT.FACE <LINK>
TIMER=1
RETURN 1

[EVENTS e_taming_pod]
ON=@LogOut
FINDID.i_taming_timer.REMOVE
EVENTS -e_taming_pod

ON=@SkillStart
SYSMESSAGELOC 946,3,502798
FINDID.i_taming_timer.REMOVE
EVENTS -e_taming_pod

ON=@Death
SYSMESSAGELOC 946,3,502798
FINDID.i_taming_timer.REMOVE
EVENTS -e_taming_pod

ON=@SpellCast
SYSMESSAGELOC 946,3,502798
FINDID.i_taming_timer.REMOVE
EVENTS -e_taming_pod

[ITEMDEF i_released_remove_timer]
ID=i_memory
NAME=Released remove
TYPE=T_EQ_SCRIPT

ON=@Timer
CONT.REMOVE
RETURN 1

[FUNCTION tame]
LOCAL.TMP <NEW>
LOCAL.TMP2 <OBJ>
OBJ <ARGN1>
OBJ.FLAGS |= statf_pet
OBJ.FINDID.i_released_remove_timer.REMOVE
OBJ.TAG.DONO=<UID>
OBJ.KARMA=0
OBJ.FAME=5000
SERV.NEWITEM i_memory
NEW.LINK <UID>
NEW.MORE2 <TIME>
NEW.COLOR 042
NEW.MOREP <OBJ.P>
OBJ.EQUIP <NEW>
IF !(<OBJ.FINDID.i_bonded_timer>) && !(<OBJ.ISEVENT.e_bonded>)
SERV.NEWITEM i_bonded_timer
OBJ.EQUIP <NEW>
ENDIF
IF (<OBJ.TAG0.STATDROPTAME>) && !(<OBJ.TAG0.JADROPOUSTAT>)
MESSAGE @946,3,1 <OBJ.NAME> teve seus status reduzidos.
OBJ.MAXHITS /= 2
OBJ.TAG.JADROPOUSTAT=1
OBJ.STR /= 2
OBJ.DEX /= 2
OBJ.INT /= 2
OBJ.HITS=<OBJ.MAXHITS>
ENDIF
IF !(STRMATCH(*e_Horses*,<OBJ.TEVENTS>)) && !(<OBJ.ISEVENT.e_horses>)
OBJ.EVENTS +E_HORSES
ENDIF
OBJ.UPDATE
NEW <LOCAL.TMP>
OBJ <LOCAL.TMP2>

[ITEMDEF i_bonded_timer]
ID=i_memory
TYPE=T_EQ_SCRIPT
NAME=Bond timer

ON=@Equip
TIMER=<EVAL 60*60*24>
MORE1=7

ON=@Timer
IF !(<CONT.FLAGS>&statf_pet)
REMOVE
ELIF (<CONT.FOOD> < <EVAL <CONT.MAXFOOD>-2>)
MORE1=7
ELSE
MORE1 -= 1
IF !(<MORE1>)
CONT.EVENTS +e_bonded
CONT.UPDATE
REMOVE
ENDIF
ENDIF
TIMER=<EVAL 60*60*24>
RETURN 1

[EVENTS e_bonded]
ON=@Death
IF (<FOOD> >= <EVAL <MAXFOOD>-5>)
FLAGS &= ~statf_war
memoryfindtype.memory_war_targ.remove
LOCAL.NEW=<NEW>
SERV.NEWITEM i_bonded_remove
EQUIP <NEW>
NEW=<LOCAL.NEW>
TAG.LASTCOR=<COLOR>
COLOR=colors_gray
HITS=<MAXHITS>
FLAGS |= <def.statf_invul>
SERV.NEWITEM i_memory
NEW.LINK=<TAG0.DONO>
NEW.COLOR=<DEF.MEMORY_IPET>
NEW.CONT=<UID>
ACTION -1
RETURN 1
ENDIF

ON=@Dclick
IF (<FLAGS>&statf_invul)
RETURN 1
ENDIF

ON=@Attack
IF (<FLAGS>&statf_invul)
ACTION -1
RETURN 1
ENDIF

ON=@Hittry
IF (<FLAGS>&statf_invul)
ACTION -1
RETURN 1
ENDIF

ON=@Spellcast
IF (<FLAGS>&statf_invul)
RETURN 1
ENDIF

ON=@GetHit
IF (<FLAGS>&statf_invul)
RETURN 1
ENDIF

ON=@SpellEffect
IF (<ARGN1>==59)
FLAGS &= ~statf_invul
FINDID.i_bonded_remove.REMOVE
COLOR=<TAG0.LASTCOR>
TAG.LASTCOR
ENDIF

ON=@ClientToolTip
SRC.ADDCLILOC 1049608
IF (<FLAGS>&statf_invul)
SRC.ADDCLILOC 1074242
ENDIF

[ITEMDEF i_bonded_remove]
ID=i_memory
TYPE=T_EQ_SCRIPT
NAME=Bond remove

ON=@Equip
TIMER=<EVAL 60*60*24>

ON=@Timer
CONT.REMOVE
RETURN 1

[EOF]

el primero es el del dragon leveleable y el otro es de tamming , creo q era ese