Ayuda Item [Resuelto]

Mi problema es que no me anda el delay de las piedras, y no entiendo por que motivo :\... Deje descanzar el script para agarrarlo fresco, pero no le encuentro el motivo -.-"

Código:

[ITEMDEF i_piedra_anuncio]
NAME=Anuncio de Posicion
ID=i_grave_stone


CATEGORY=!Custom
SUBSECTION=Stones
DESCRIPTION=Anunciadora

on=@Click
MESSAGE= @037 <NAME>
RETURN 1

ON=@dclick
if <src.findid.i_timer_piedra.uid>
   src.sysmessage @55 Debes de esperar para volver utilizar esta piedra.
   return 1
else
   Serv.b @55 <src.name>, merodea la zona de Britania.
   return 1
endif

El otro item (el delay) seria:

Código:

[ITEMDEF i_timer_piedra]
ID=i_memory
NAME=ANUNCIO
WEIGHT=0
TYPE=t_eq_script

ON=@Create
ATTR=attr_invis|attr_decay

ON=@Equip
SRC.TAG.ANUNCIO=1
TIMER=1
MORE=60
RETURN 0

ON=@Timer
Src.sysmessage @55 Puedes volver a usar cualquier piedra Anunciadora.
REMOVE

Creo que lo que buscás es que la piedra de Anuncio tengo un Delay de 60 segundos para volver a usarla no?

Siendo así... Esta bien, pero sobran algunas cosas.
por ejemplo:

ON=@dclick
if <src.findid.i_timer_piedra.uid>
el UID sobra... Sacaselo.

Depues en el Item de delay ese... El more no esta cumpliendo ninguna función porque no es consultado en ningún momento.
Poné directamente TIMER=60 y ya tendría que estar andando.
El Tag tambien sobra porque no lo usás.

El More ahí no te sirve porque generalmente se usa en items donde la cuenta regresiva tiene que ser vista en tu cabeza por ejemplo... Como en AUO las travel Stones por darte un ejemplo.
Y así solo no funca... Tenés que darle más o menos así:







[itemdef i_delay_con_cuenta_lalalala]
Name=Delay con numeros en mi cabecita
id=i_memory
type=t_eq_script

on=@create
more1=30 // Tiempo de conteo 30 segundos
WEIGHT=1
ATTR=attr_invis|attr_decay

on=@equip //puede ser disparado en otro trigger como create por ejemplo
timer=1 //en este caso el timer si sera de 1 seg porque es el tiempo en el
//que decrementa el valor de MORE


ON=@Timer //cuando pasa un seg
IF <EVAL(<more1> < 1)> //Si el valor de more llego a 0
CONT.GO "donde sea"
REMOVE
ENDIF

cont.message @0482 <EVAL(<more1>)> //Si no llego a 0 lo dice en tu marote
more1=<more1>-1 // Y va restando 1
timer=1 //Vuelve a setear el timer en 1 sec
return 1






Fijate

muchas gracias...


la verdad que ahora que me doy cuenta si.... tome el timmer como tag pensando que no habia puesto tag (que no se para que lo psue tampoco).... esto es por agarrar y querer meter restricciones temporales despues de editar un Color War jajajajajjajajaj xD lleno de tag....



Muchisimas gracias....

el more 1 lo habia puesto por que pensaba que te avisaba cuando estaba listo el tiempo de restriccion, y la verdad que fue patetico y asqueroso xD!


Mcuhas gracias Gab !