Ultima Online en Español
Bienvenido a Ultima Online en Español. Por favor, regístrate o entra con tu cuenta.

Saludos.

El equipo del Foro.
Últimos temas
» Inception busca scripter.
Jue 31 Dic 2015 - 2:20 por Lethal

» Equipo para Servidor
Mar 3 Nov 2015 - 13:39 por Kork

» Busco un buen scripter para proyecto server pvp
Dom 19 Jul 2015 - 3:57 por rastrero

» Ultima Azteca
Lun 29 Jun 2015 - 3:31 por chronoMx

» AYUDA SCRIPT
Mar 3 Mar 2015 - 3:35 por rastrero

» NuevaUO (BUSCA COLABORADORES)
Lun 6 Oct 2014 - 10:46 por pushim

» Ultima Alianza
Sáb 26 Jul 2014 - 14:32 por Jecht

» Versiones de Cliente
Mar 22 Jul 2014 - 2:52 por Lethal

» Insane World
Sáb 19 Jul 2014 - 18:00 por Lethal

Staff
Admin Oupman [Fundador]
Lethal [Administrador] Inferno Networks
Rastrero [Administrador]
Mr.H (Moderador)
Servidores

sphere_admin.scp (Español BETA 1)

Ver el tema anterior Ver el tema siguiente Ir abajo

sphere_admin.scp (Español BETA 1)

Mensaje por Admin OuPMaN el Mar 31 Ago 2010 - 16:59

Seguramente miraréis este post nada más verlo. Os recuerdo que al editar un script sphere no usa un lenguaje unicode (UTF-Cool. Por lo tanto no podréis usar ni ñ, ni tildes. En la líneas que empiezan comentadas si que podéis usarlas. Fijaros en como tenéis que dejar la cabecera. Cuando pongáis un script en el post pulsad abajo en opciones DESACTIVAR HTML para que no la líe a interpretar cosas tipo eval y otros que también se usan en HTML.

Código:
//****************************************************************************
//SPHERE by : Menasoft ©️1997-2010
http://www.sphereserver.net
// Todas las script de Sphere son Copyright Menasoft & Partners.
// Este archivo puede ser editado para su libre personalizacion, pero no puede ser distribudio
// por entero o en parte, en ninguna parte sin el permiso de Menasoft & Partners.  Toda donación y contribución
// se convierte Copyright Mensasoft & Partners.
// Por lo cual el fundador de este proyecto lo dirige como una contribución a Menasoft & Partners.
// Y Menasoft & Partners tiene todos los derechos sobre esto
// The creator of this proyect offers this like a contribution to Menasoft & Partners. Menasoft & Partners is
// the owner of this proyect.
//****************************************************************************
// ULTIMA ACTUALIZACION: 19-January-2008
// ULTIMA TRADUCCION: 31-Agosto-2010
// EDICIONES PARA LA TRADUCCION: NINGUNA
// TRADUCTOR: OuPMaN (davidcrma)

VERSION=0.56b

// SphereServer 0.56* Consola de Administracion
//
//
// Pensado para pantalla 800x600
//
// Escrito por Radiant - Ultima Modificacion: 19-01-2008 (MrSugarCube)
//- Posicion Inicial del dialogo=0,21
//- Pagina inicial de Viendo Cliente=Acciones
//- Quitado el Plevel para tener más espacio para el nombre del pj
//- Cerrando Viendo Cliente vuelves a la página inicial
//- Añadido numero de clientes.
//- Añadido Boton Borrar Nota
//- Modifica el cliente cuando se cambia flags

[DEFNAME admin_options]
// Si quieres que clientes de menos o igual plevel no vean la IP
// de clientes de igual o mayor plevel escribe 1 en admin_hideips
// (el plevel 7 siempre vera todas las IP)
admin_hideips 0
// Si quieres que clientes de menor plevel no vean a los de mayor que esten en invisible
// invisible (.invis) en la lista, escribe 1 en admin_hidehighpriv
admin_hidehighpriv 0
// Cuando un flag es configurado o desconfigurado, es necesario tiempo para que el pj
// se actualice para que la nueva configuracion tome efecto. Esto lleva un control de tiempo
// para llamar a UPDATEX,UPDATE y RESENDTOOLTIP, con esto
// se basa cuanto se tarda en cambiar un flag y de que forma.
admin_updatexflags        statf_invisible|statf_insubstantial|statf_hidden
admin_updateflags        statf_invul|statf_freeze|statf_stone|statf_hallucinating|statf_poisoned|statf_criminal|statf_nightsight
admin_resendtooltipflags    statf_incognito

[DEFNAME admin_strings]
// Titulo para los niveles de privilegio (Plevel)
admin_plevel_0        "Invitado/Guest"
admin_plevel_1        "Jugador/Player"
admin_plevel_2        "Counselor/Consejero"
admin_plevel_3        "Seer/Profeta"
admin_plevel_4        "Game Master/Maestro del Juego"
admin_plevel_5        "Developer/Promotor"
admin_plevel_6        "Administrator/Administrador"
admin_plevel_7        "Owner/Propietario"
// Titulos para expansion de UO
admin_resdisp_0        "Pre-T2A"
admin_resdisp_1        "The 2nd Age"
admin_resdisp_2        "Lord Blackthorn's Revenge"
admin_resdisp_3        "Age Of Shadows"
admin_resdisp_4        "Samurai Empire"
admin_resdisp_5        "Mondain's Legacy"
// Titles para flags, originariamente extraídos de Axis con una ligera Modificación.
admin_flag_1        "Invulnerable"
admin_flag_2        "Muerto"
admin_flag_3        "Paralizado"
admin_flag_4        "Invisible"
admin_flag_5        "Durmiendo"
admin_flag_6        "Modo Guerra"
admin_flag_7        "Blindaje Reactivo"
admin_flag_8        "Envenenado"
admin_flag_9        "Ver de noche"
admin_flag_10        "Refleccion Magica"
admin_flag_11        "Transformado"
admin_flag_12        "Incognito"
admin_flag_13        "Hablar con Espiritus"
admin_flag_14        "Insubstancial"
admin_flag_15        "Emocion"
admin_flag_16        "Cristal de Comunicacion"
admin_flag_17        "Tiene Escudo"
admin_flag_18        "Puede Moverse con Arco"
admin_flag_19        "Hecho Piedra"
admin_flag_20        "Grabando Script"
admin_flag_21        "Volando"
admin_flag_22        "Respawn"
admin_flag_23        "Alucinando"
admin_flag_24        "Oculto"
admin_flag_25        "En casa"
admin_flag_26        "Criminal"
admin_flag_27        "Invocado"
admin_flag_28        "Mascota"
admin_flag_29        "Spawneado"
admin_flag_30        "Salvar a la paridad"
admin_flag_31        "Cabalgado"
admin_flag_32        "Montado"
// NO EDITES ESTAS LÍNEAS SI NO SABES LO QUE ESTÁS HACIENDO!!!!!

[FUNCTION admin]
if ( <getreftype> == <def.tref_serv> )
    serv.console C
    return
elseif ( !<isplayer> )
    return
endif

src.dialogclose d_sphereadmin
ctag.admin_numplayers=0
ctag.admin_page=1
serv.allclients admin_getplayers
ctag.admin_numpages=<eval (((<ctag0.admin_numplayers>-1) / 15) + 1)> // 15 players per page
dialog d_sphereadmin

[FUNCTION admin_getplayers]
// List players in CTAGs on the caller
if ((<account.plevel> > <src.account.plevel>) && (<flags> & statf_insubstantial) && (<def0.admin_hidehighpriv>))
    return
else
    src.ctag0.admin_numplayers += 1
    try src.ctag.admin_p<eval (<src.ctag0.admin_numplayers>)>=<uid>
endif

[DIALOG d_sphereadmin]
0,21
// Let's not break some (perhaps) scripts using OBJ
local.oldobj=<obj>
page 0 // Basic layout
resizepic 0 0 2620 650 397 // Background
gumppictiled 5 5 640 385 2604
gumppictiled 5 5 640 25 2624
gumppictiled 5 370 640 22 2624
gumppictiled 5 35 640 330 2624
checkertrans 5 5 640 387
dtext 10 7 0c1 SphereServer <src.version> Spanish Version Admin Panel (<serv.servname>) - Clientes: <eval <ctag0.admin_numplayers>>
button 615 5 4017 4018 1 0 0
page 1 // Player data
dtext 45 35 025 Nombre de la Acc
dtext 170 35 025 Nombre del PJ
dtext 380 35 025 Direccion IP
dtext 520 35 025 Localizacion
//dtext 540 35 025 Plevel
admin_renderdialog
obj=<local.oldobj>
if (<ctag0.admin_page> > 1)
    // Back button
    button 5 370 4014 4015 1 0 1
endif
if (<ctag0.admin_page> < <ctag0.admin_numpages>)
    // Forward button
    button 615 370 4005 4006 1 0 2
endif
dtext 275 370 0c1 Page <eval <ctag0.admin_page>> / <eval <ctag0.admin_numpages>>

[FUNCTION admin_renderdialog]
local.y=55
for x <eval ((<ctag0.admin_page> - 1) * 15) + 1> <eval (<ctag0.admin_page> * 15)>
    if (<local.x> > <ctag0.admin_numplayers>)
        return
    endif
    obj=<ctag0.admin_p<eval <local.x>>>
    if (<obj.flags> & statf_insubstantial)
        local.hue=0450
    else
        local.hue=0480
    endif
    button 10 <local.y> 4005 4006 1 0 <eval (1000 + <local.x>)>
    dtext 45 <local.y> <local.hue> <QVAL <OBJ.ACCOUNT.PLEVEL>==0?(-):<QVAL <OBJ.ACCOUNT.PLEVEL>==1?:(+)>> <obj.account>
    dtext 170 <local.y> <local.hue> <QVAL <OBJ.FINDID.i_rune_incognito.UID> ? <OBJ.FINDID.i_rune_incognito.NAME> : <obj.name>>
    // Hide IP address to people of lower or equal privilege, if desired
    if ((<obj.uid> != <uid>) && (<account.plevel> <= <obj.account.plevel>) && (<def0.admin_hideips>) && (<account.plevel> != 7))
        dtext 380 <local.y> <local.hue> x.x.x.x
    else
        dtext 380 <local.y> <local.hue> <obj.account.lastip>
    endif
    dtext 520 <local.y> <local.hue> <obj.p.x>,<obj.p.y>,<obj.p.z>,<obj.p.m>
    //  dtext 540 <local.y> <local.hue> <obj.account.plevel> (<def0.admin_plevel_<eval <obj.account.plevel>>>)
    local.y += 20
end

[DIALOG d_sphereadmin BUTTON]
on=0
    clearctags admin_p
    ctag.admin_numplayers=
    ctag.admin_numpages=

on=1 // Back button
    ctag.admin_page -= 1
    if (<ctag0.admin_page> < 1)
        // Bad! And shouldnt happen
        sysmessage Error: admin_page value went too low, please report (<ctag0.admin_page> / <ctag0.admin_numpages>)
        ctag.admin_page=1
    endif
    dialog d_sphereadmin

on=2 // Forward button
    ctag.admin_page += 1
    if (<ctag0.admin_page> > <ctag0.admin_numpages>)
        // Bad! Should also not happen
        sysmessage Error: admin_page value went too high, please report (<ctag0.admin_page> / <ctag0.admin_numpages>)
        ctag.admin_page=<ctag0.admin_numpages>
    endif
    dialog d_sphereadmin

on=1001,65535 // Player buttons
    try uid.<ctag.admin_p<eval <argn> - 1000>>.dialog d_sphereplayertweak, 2

[DIALOG d_sphereplayertweak]
0,21
src.dialogclose d_sphereplayertweak
page 0 // Basic layout
resizepic 0 0 2620 650 397 // Background
gumppictiled 5 5 640 385 2604
gumppictiled 5 5 640 25 2624
gumppictiled 5 35 140 355 2624
gumppictiled 150 35 495 355 2624
checkertrans 5 5 640 387
dtext 10 7 0c1 SphereServer <src.version> Spanish Version Admin Panel (<serv.servname>) - Mirando Cliente
button 615 5 4017 4018 1 0 0
button 585 5 4008 4009 1 0 1
button 5 35 4005 4006 0 1 0
dtext 40 37 0480 Informacion
button 5 55 4005 4006 0 2 0
dtext 40 57 0480 Acciones
button 5 77 4005 4006 1 0 2
dtext 40 77 0480 Notas
button 5 117 4005 4006 0 4 0
dtext 40 117 0480 Caracter
button 5 137 4005 4006 0 3 0
dtext 40 137 0480 Flags de Estado
page 1
dtext 160 35 0c1 Nombre:
dtext 300 35 0480 <name>
dtext 460 35 0c1 Uid:
dtext 500 35 0480 <uid>
dtext 160 55 0c1 Nombre de la cuenta:
dtext 300 55 0480 <account.name>
dtext 160 75 0c1 Titulo
dtext 300 75 0480 <title>
dtext 160 95 0c1 Plevel:
dtext 300 95 0480 <account.plevel> (<def0.admin_plevel_<eval <account.plevel>>>)
dtext 160 135 0c1 Version del Cliente
dtext 300 135 0480 <clientversion> / <reportedcliver>
dtext 160 155 0c1 Resdisp:
dtext 300 155 0480 <account.resdisp> (<def0.admin_resdisp_<eval <account.resdisp>>>)
dtext 160 195 0c1 Primera entrada:
dtext 300 195 0480 <account.firstconnectdate> from <qval ((<src.account.plevel> <= <account.plevel>) && (<def0.admin_hideips>) && (<src.account.plevel> != 7) ? "x.x.x.x" : <account.firstip>>
dtext 160 215 0c1 Ultima entrada:
dtext 300 215 0480 <account.lastconnectdate> from <qval ((<src.account.plevel> <= <account.plevel>) && (<def0.admin_hideips>) && (<src.account.plevel> != 7) ? "x.x.x.x" : <account.lastip>>
dtext 160 255 0c1 Localizacion:
dtext 300 255 0480 <p.x>,<p.y>,<p.z>,<p.m>
dtext 160 295 0c1 Asesinatos:
dtext 300 295 0480 <kills>
dtext 360 295 0c1 Veces que ha muerto:
dtext 540 295 0480 <deaths>
dtext 160 315 0c1 Nivel de Comida
dtext 300 315 0480 <food>
page 2
button 160 40 4005 4006 1 0 21
dtext 200 40 0480 Ir a este jugador
button 160 60 4005 4006 1 0 22
dtext 200 60 0480 Ir a este jugador en invis
button 160 80 4005 4006 1 0 23
dtext 200 80 0480 Invocar a este jugador
button 160 100 4005 4006 1 0 29
dtext 200 100 0480 Invocar a este jugador en una jaula
button 160 120 4005 4006 1 0 24
dtext 200 120 0480 Seguir a este jugador
button 160 140 4005 4006 1 0 25
dtext 200 140 0480 <qval (<account.jail>) ? Liberar:Encarcelar> este jugador
button 160 160 4005 4006 1 0 26
dtext 200 160 0480 <qval (<flags> & statf_dead)?Resucitar:Matar> este jugador
button 160 180 4005 4006 1 0 27
dtext 200 180 0480 Desconectar a este jugador del servidor
button 160 200 4005 4006 1 0 28
dtext 200 200 025 Desconectar y banear a este jugador del servidor
page 3
local.flag=01
local.ox=160
local.oy=40
for x 0 31
    checkbox <eval <local.ox>> <eval <local.oy>> 210 211 <hval (<flags> & <local.flag>)> <eval 300 + <local.x>>
    dtext <eval <local.ox> + 40> <eval <local.oy>> 0480 <def0.admin_flag_<eval <local.x> + 1>>
    // Workaround for sphere bug - local.flag=<hval <local.flag> << 1> attempts to evaluate << !
    local.flag="<local.flag> << 1"
    local.flag=<hval <local.flag>>
    local.oy += 20
    if (<local.oy> > 360)
        local.ox += 200
        local.oy = 40
    endif
end
button 360 360 4005 4006 1 0 31
dtext 400 360 0c1 Configurar flags
page 4
dtext 160 35 0c1 Nombre:
dtext 300 35 0480 <name>
dtext 460 35 0c1 Uid:
dtext 500 35 0480 <uid>
dtext 160 55 0c1 Titulo:
dtext 300 55 0480 <title>
dtext 160 95 0c1 Fuerza:
dtext 300 95 0480 <str>
dtext 360 95 0c1 Vida:
dtext 540 95 0480 <hits>/<maxhits>
dtext 160 115 0c1 Destreza:
dtext 300 115 0480 <dex>
dtext 360 115 0c1 Estamina:
dtext 540 115 0480 <stam>/<maxstam>
dtext 160 135 0c1 Inteligencia:
dtext 300 135 0480 <int>
dtext 360 135 0c1 Mana:
dtext 540 135 0480 <mana>/<maxmana>
dtext 160 155 0c1 Karma:
dtext 300 155 0480 <karma>
dtext 360 155 0c1 Fama:
dtext 540 155 0480 <fame>

[DIALOG d_sphereplayertweak BUTTON]
on=0 1
    src.dialog d_sphereadmin

on=2
    dialog d_sphereplayernotes

on=21
    src.go <p>

on=22
    src.invis 1
    src.go <p>

on=23
    go <src.p>

on=24
    if ( <src.uid> != <uid> )
        src.follow <uid>
    endif
on=25
    if (<account.jail>)
        forgive
    else
        jail
    endif

on=26
    if (<flags> & statf_dead)
        resurrect
    else
        hits=0
        // Use kill here if you want the lightning effect
    endif

on=27
    disconnect

on=28
    kick

on=29
    summoncage

on=31
    local.updatexflags = <flags>&<def0.admin_updatexflags>
    local.updateflags = <flags>&<def0.admin_updateflags>
    local.resendtooltipflags = <flags>&<def0.admin_resendtooltipflags>
    local.flag=01
    for x 0 31
        if (<argchk[<eval 300 + <local.x>>]>)
            flags |= <local.flag>
        else
            flags &= ~<local.flag>
        endif
        // Workaround for sphere bug - local.flag=<hval <local.flag> << 1> attempts to evaluate << !
        local.flag="<local.flag> << 1"
        local.flag=<hval <local.flag>>
    endfor
    if ((<flags>&<def0.admin_updatexflags>) != <local.updatexflags>)
        updatex
    elseif ((<flags>&<def0.admin_updateflags>) != <local.updateflags>)
        update
    elseif ((<flags>&<def0.admin_resendtooltipflags>) != <local.resendtooltipflags>)
        resendtooltip
    endif
    src.sysmessage Flags modified!

[DIALOG d_sphereplayernotes]
0,21
src.dialogclose d_sphereplayernotes
page 0 // Basic layout
resizepic 0 0 2620 650 397 // Background
gumppictiled 5 5 640 385 2604
gumppictiled 5 5 640 25 2624
gumppictiled 5 35 140 355 2624
gumppictiled 150 35 495 330 2624
gumppictiled 150 370 495 20 2624
checkertrans 5 5 640 387
dtext 10 7 0c1 SphereServer <src.version> Spanish Version Admin Panel (<serv.servname>) - Notas del Cliente
button 615 5 4017 4018 1 0 0
button 585 5 4008 4009 1 0 1
button 5 35 4005 4006 1 0 2
dtext 40 37 0480 Informacion
button 5 55 4005 4006 1 0 3
dtext 40 57 0480 Acciones
button 5 77 4005 4006 0 1 0
dtext 40 77 0480 Notas
button 5 117 4005 4006 1 0 4
dtext 40 117 0480 Caracter
button 5 137 4005 4006 1 0 5
dtext 40 137 0480 Flags de Estado
dtext 200 35 0c1 Aquí tu puedes ver y/o escribir notas en esta cuenta.
dtext 200 55 0c1 Esta cuenta tiene <eval 0<account.tag0.numnotes>> notas. Viendo 4 notas por pagina.
button 160 75 4005 4006 1 0 10
dtext 200 75 0480 Escribir nota en esta cuenta (<account>)
if (0<account.tag0.numnotes>)
    local.page=1
    local.oy=120
    page 1
    for x 1 <account.tag0.numnotes>
        if (<local.oy> > 300)
            local.oy = 120
            local.page += 1
            button 615 370 4005 4006 0 <eval <local.page>> 0 // Forward button
            page <eval <local.page>>
            button 150 370 4014 4015 0 <eval <local.page> - 1> 0 // Back button
        endif
        resizepic 155 <eval <local.oy>> 9350 480 50
        dtext 160 <eval <local.oy>> 0 Added by <account.tag0.note_<eval <local.x>>_by> at <account.tag0.note_<eval <local.x>>_time>
        dtext 160 <eval <local.oy> + 15> 0480 <account.tag0.note_<eval <local.x>>>
        button 600 <eval <local.oy>> 4017 4018 1 0 <EVAL 10+<LOCAL.X>>
        local.oy += 60
    end
endif

[DIALOG d_sphereplayernotes BUTTON]
on=0 1
    src.dialog d_sphereadmin

on=2
    dialog d_sphereplayertweak 1

on=3
    dialog d_sphereplayertweak 2

on=4
    dialog d_sphereplayertweak 4

on=5
    dialog d_sphereplayertweak 3

on=10
    if ( <src.account.plevel> > <account.plevel> )
        src.ctag.notefor=<uid>
        src.promptconsole admin_addnote Escribe la nota:
    else
        src.sysmessage No puedes escribir una nota en cuentas de mayor privilegio.
        src.dialog d_sphereplayernotes
    endif

on=11 500
    if ( <src.account.plevel> > <account.plevel> )
        src.ctag.notefor=<uid>
        src.admin_removenote <eval (<ARGN1>-10)>
    else
        src.sysmessage No puedes cambiar una nota escrita por alguien de mayor privilegio.
        src.dialog d_sphereplayernotes
    endif

[FUNCTION admin_removenote]
local.note=<argv[0]>
local.oldobj=<obj>
obj=<ctag.notefor>
IF (<LOCAL.NOTE>==<OBJ.ACCOUNT.TAG.NUMNOTES>)//if it was the last note no need to sort
    TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>
    TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>_BY
    TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>_TIME
ELSE //sort note list
    WHILE (<LOCAL.NOTE> < <ACCOUNT.TAG0.NUMNOTES>)
        TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>=<OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>+1>>
        TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>_BY=<OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>+1>_BY>
        TRYSRV OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>>_TIME=<OBJ.ACCOUNT.TAG.NOTE_<EVAL <LOCAL.NOTE>+1>_TIME>
        LOCAL.NOTE += 1
    end
endif
TRYSRV OBJ.ACCOUNT.TAG0.NUMNOTES=<EVAL <OBJ.ACCOUNT.TAG0.NUMNOTES>-1>
SYSMESSAGE Nota eliminada de la cuenta <obj.account>!
OBJ.DIALOG d_sphereplayernotes
OBJ=<LOCAL.OLDOBJ>

[FUNCTION admin_addnote]
local.oldobj=<obj>
obj=<ctag.notefor>
local.name=<name>
TRYSRV obj.account.tag.numnotes=<eval <obj.account.tag0.numnotes> + 1>
TRYSRV obj.account.tag.note_<eval <obj.account.tag0.numnotes>>=<args>
TRYSRV obj.account.tag.note_<eval <obj.account.tag0.numnotes>>_by=<local.name>
TRYSRV obj.account.tag.note_<eval <obj.account.tag0.numnotes>>_time=<serv.rtime>
sysmessage Note added to account <obj.account.name>!
obj.dialog d_sphereplayernotes
obj=<local.oldobj>
avatar
Admin OuPMaN
Admin

Mensajes : 214
Puntos : 3094
Reputación : 18
Fecha de inscripción : 03/04/2010
Edad : 20
Localización : Linares (España)
Empleo /Ocio : Estudiante, Pianista, Compositor y Diseñador de Webs

Ver perfil de usuario http://ayudasphereserver.forosactivos.net

Volver arriba Ir abajo

Ver el tema anterior Ver el tema siguiente Volver arriba

- Temas similares

 
Permisos de este foro:
No puedes responder a temas en este foro.